masqmail

view configure.ac @ 363:02bc0331e390

find changesets by author, revision, files, or words in the commit message
Removed support for openssl linking It had been rarely used and could have caused legal problems. For explanations, see this mail message: Date: Sun, 04 Sep 2011 17:35:23 +0200 From: markus schnalke <meillo@marmaro.de> To: masqmail@marmaro.de Subject: [masqmail] RFC: Removal of configure options Message-ID: <1R0EjD-4aX-00@serveme.home.schnalke.org>
author markus schnalke <meillo@marmaro.de>
date Wed, 14 Sep 2011 12:07:34 +0200
parents 4916f9df5051
children 72653295b75d
line source
1 dnl Process this file with autoconf to produce a configure script.
2
3 AC_PREREQ(2.59)
4 AC_INIT(masqmail, 0.3.4-dev, meillo@marmaro.de)
5 AC_CONFIG_SRCDIR([src/masqmail.c])
6 AM_CONFIG_HEADER(config.h)
7 AM_INIT_AUTOMAKE()
8
9 dnl Checks for programs.
10
11 dnl Checks for libraries.
12
13 AC_PROG_CC
14 AC_ISC_POSIX
15 AC_STDC_HEADERS
16 dnl AC_ARG_PROGRAM
17 AC_PROG_RANLIB
18
19 PKG_CHECK_MODULES(GLIB, glib-2.0)
20 dnl # use the next line to use glib-1.2
21 dnl PKG_CHECK_MODULES(GLIB, glib)
22
23 AC_SUBST(GLIB_LIBS)
24 AC_SUBST(GLIB_CFLAGS)
25
26 dnl resolver support (default is use it)
27 AC_ARG_ENABLE(resolver,
28 [ --disable-resolver disable resolver support],
29 if test "$enable_resolver" != 'no'; then
30 resolver_enabled='yes'
31 fi,
32 resolver_enabled='yes'
33 )
34
35 if test "$resolver_enabled" = yes; then
36 AC_DEFINE(ENABLE_RESOLVER, 1, [If the resolver is to be used])
37 dnl checks necessary for libc5:
38 dnl if there is res_search in libc, it is probably libc5
39 dnl if not, it is probably libc6 and we need libresolv
40 AC_CHECK_LIB(c, res_search, need_resolv=no, need_resolv=yes)
41 if test "$need_resolv" = yes; then
42 AC_CHECK_LIB(resolv, res_search,
43 has_resolv=yes; RESOLV_LIBS="-lresolv",
44 has_resolv=no)
45 if test "$has_resolv" = no; then
46 saved_LIBS="$LIBS"
47 LIBS="$LIBS -lresolv"
48 AC_MSG_CHECKING(for res_search in -lresolv)
49 AC_TRY_LINK([#include <resolv.h>],
50 [res_search (0, 0, 0, 0, 0);],
51 RESOLV_LIBS="-lresolv"; has_resolv=yes; AC_MSG_RESULT(yes),
52 AC_MSG_RESULT(no));
53 LIBS="$saved_LIBS"
54 fi
55 if test "$has_resolv" = no; then
56 AC_MSG_ERROR("no libresolv")
57 RESOLV_LIBS=''
58 fi
59 fi
60 else
61 RESOLV_LIBS=''
62 fi
63 AC_SUBST(RESOLV_LIBS)
64
65 dnl if there is no getline, we define it using getdelim in src/masqmail.h
66 AC_CHECK_FUNCS(getline)
67
68 dnl if there is no fdatasync, we define it to fsync in src/masqmail.h
69 AC_CHECK_FUNCS(fdatasync)
70
71 dnl Checks for header files.
72 AC_HEADER_STDC
73 AC_CHECK_HEADERS(fcntl.h sys/time.h syslog.h unistd.h)
74
75 dnl Checks for typedefs, structures, and compiler characteristics.
76 AC_C_CONST
77 AC_TYPE_PID_T
78 AC_TYPE_SIZE_T
79 AC_HEADER_TIME
80 AC_STRUCT_TM
81
82 dnl Checks for library functions.
83 AC_FUNC_FNMATCH
84 AC_TYPE_SIGNAL
85 AC_FUNC_STRFTIME
86 AC_FUNC_VPRINTF
87 AC_CHECK_FUNCS(select socket strerror strstr)
88
89 dnl user and group configuration
90 AC_ARG_WITH(user,
91 [ --with-user=USER set user [mail]],
92 )
93 if test "x$with_user" = 'x'; then
94 with_user='mail'
95 fi
96
97 AC_ARG_WITH(group,
98 [ --with-group=GROUP set group [mail]],
99 )
100 if test "x$with_group" = 'x'; then
101 with_group='mail'
102 fi
103
104 dnl debugging support (default is use it)
105 AC_ARG_ENABLE(debug,
106 [ --disable-debug disable debugging],
107 if test "x$enable_debug" != 'xno'; then
108 debug_enabled='yes'
109 fi,
110 debug_enabled='yes'
111 )
112 if test "x$debug_enabled" = xyes; then
113 AC_DEFINE(ENABLE_DEBUG, 1, [If debugging is enabled])
114 fi
115
116 AC_DEFINE_UNQUOTED(DEF_MAIL_USER, "${with_user}", [The mail user])
117 AC_SUBST(with_user)
118 AC_DEFINE_UNQUOTED(DEF_MAIL_GROUP, "${with_group}", [The mail group])
119 AC_SUBST(with_group)
120
121 dnl optional features
122 MD5_LIBS=''
123 BASE64_LIBS=''
124
125 dnl auth support (default is to not use it)
126 AC_ARG_ENABLE(auth,
127 [ --enable-auth enable AUTH (RFC 2554) client support],
128 if test "x$enable_auth" != 'xno'; then
129 auth_enabled='yes'
130 fi,
131 )
132 if test "x$auth_enabled" = xyes; then
133 AC_DEFINE(ENABLE_AUTH, 1, [If AUTH is enabled])
134 BASE64_LIBS='base64/libbase64.a'
135 need_md5='yes'
136 fi
137 AC_SUBST(BASE64_LIBS)
138
139 if test "x$need_md5" = 'xyes'; then
140 MD5_LIBS='md5/libmd5.a'
141 fi
142 AC_SUBST(MD5_LIBS)
143
144 dnl ident support (default is to not use it)
145 IDENT_LIBS=''
146 AC_ARG_ENABLE(ident,
147 [ --enable-ident enable ident (RFC 1413) support],
148 if test "x$enable_ident" != 'xno'; then
149 ident_enabled='yes'
150 fi,
151 )
152 AC_SUBST(has_ident)
153 if test "x$ident_enabled" = xyes; then
154 AC_DEFINE(ENABLE_IDENT, 1, [If ident is enabled])
155 AC_CHECK_LIB(ident, ident_id, IDENT_LIBS='-lident', IDENT_LIBS='libident/libident.a')
156 fi
157 AC_SUBST(IDENT_LIBS)
158
159 dnl liblockfile
160 AC_ARG_WITH(liblockfile,
161 [ --with-liblockfile use liblock (for Debian)],
162 )
163 if test "x$with_liblockfile" = 'xno'; then
164 with_liblockfile=''
165 fi
166 if test "x$with_liblockfile" != 'x'; then
167 with_liblockfile='yes'
168 fi
169 if test "x$with_liblockfile" = xyes; then
170 AC_CHECK_LIB(lockfile, maillock, has_lockfile=yes, AC_MSG_ERROR("no liblockfile"))
171 LOCKFILE_LIBS='-llockfile'
172 AC_DEFINE(USE_LIBLOCKFILE, 1, [If liblockfile is to be used])
173 else
174 LOCKFILE_LIBS=''
175 fi
176 AC_SUBST(LOCKFILE_LIBS)
177 AC_SUBST(USE_LIBLOCKFILE)
178
179 dnl log and spool directories
180 AC_ARG_WITH(logdir,
181 [ --with-logdir=DIR set log directory [/var/log/masqmail]],
182 ,
183 with_logdir='/var/log/masqmail/'
184 )
185 AC_DEFINE_UNQUOTED(LOG_DIR, "${with_logdir}", [The log directory])
186 AC_SUBST(with_logdir)
187
188 AC_ARG_WITH(spooldir,
189 [ --with-spooldir=DIR set spool directory [/var/spool/masqmail]],
190 ,
191 with_spooldir='/var/spool/masqmail/'
192 )
193 AC_DEFINE_UNQUOTED(SPOOL_DIR, "${with_spooldir}", [The spool directory])
194 AC_SUBST(with_spooldir)
195
196 dnl configuration file
197 AC_ARG_WITH(confdir,
198 [ --with-confdir directory for configuration [/etc/masqmail]],
199 ,
200 with_confdir='/etc/masqmail'
201 )
202 AC_DEFINE_UNQUOTED(CONF_DIR, "${with_confdir}", [The configuration file location])
203 AC_SUBST(with_confdir)
204
205 test "x$prefix" = xNONE && prefix="$ac_default_prefix"
206
207 dnl well, /me/ thought that autoconf should make things _easy_ ... -- oku
208 dnl I needed the two `eval's to get the variable expanded in all cases -- meillo
209 dnl this is just horrible! -- meillo
210 AC_DEFINE_UNQUOTED(DATA_DIR, "`eval eval echo $datadir`/masqmail", [The data directory])
211
212 dnl gymnastics to get the correct path where masqmail should be installed
213 dnl we need this to call ourselves in failmsg.c
214 if test "x${exec_prefix}" != 'xNONE'; then
215 AC_DEFINE_UNQUOTED(SBINDIR, "${exec_prefix}/sbin", [The sbin directory])
216 else
217 if test "x${prefix}" != 'xNONE'; then
218 AC_DEFINE_UNQUOTED(SBINDIR, "${prefix}/sbin")
219 else
220 AC_DEFINE_UNQUOTED(SBINDIR, "/usr/sbin")
221 fi
222 fi
223
224 AC_OUTPUT(Makefile \
225 src/Makefile \
226 src/base64/Makefile \
227 src/md5/Makefile \
228 src/libident/Makefile \
229 man/Makefile
230 )